Question

Using SQL Server 2000

Date like 20120101, 20120201, 20120301...

Fomat is yyyymmdd

I want to display month and year from the date like 01/2012, 02/2012, 03/2012…

Expected Output

01/2012
02/2012
03/2012

I don’t want 1/2012, 2/2012, 3/2012...

Can any one give me a idea or query help….

Answer 1

You can use something like this:

DECLARE @input VARCHAR(20) 
SET @input = '20120101'

-- convert the 20120101 to a DATETIME    
DECLARE @thedate DATETIME
SELECT @thedate = CONVERT(DATETIME, @input, 112)

-- reformat that DATETIME to your needs    
DECLARE @output VARCHAR(20)

SET @output = RIGHT('00' + CAST(DATEPART(MONTH, @thedate) AS VARCHAR(2)), 2) + 
              '/' + CAST(DATEPART(YEAR, @thedate) AS VARCHAR(4))

SELECT @output

You could “hide” this functionality into a user-defined function to make it more easily usable in your code:

CREATE FUNCTION dbo.MonthYearFromDate (@input VARCHAR(20))
RETURNS VARCHAR(20)
AS BEGIN
    DECLARE @thedate DATETIME
    SELECT @thedate = CONVERT(DATETIME, @input, 112)

    DECLARE @output VARCHAR(20)
    SET @output = RIGHT('00' + CAST(DATEPART(MONTH, @thedate) AS VARCHAR(2)), 2) + '/' + CAST(DATEPART(YEAR, @thedate) AS VARCHAR(4))

    RETURN @output
END

and then you can call this like so:

SELECT dbo.MonthYearFromDate('20120515')

and get the output

05/2012