Question

Using Sql Server 2008, developed a view “vw_MasterView” I get this error:

Conversion failed when converting the nvarchar value 'SELECT * FROM VW_MASTERVIEW v WHERE 1=1  AND v.ClinicId = '' to data type int.

when I run the following stored procedure:

USE [xxxxxxx]
GO

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
ALTER PROCEDURE [dbo].[ClientSummary1]
    @LocationId int,
    @startDate datetime,
    @endDate datetime,
    @userName nvarchar(50)
AS
    declare @sql nvarchar(2000);
    SET NOCOUNT ON
    set @sql = 'SELECT * FROM VW_MASTERVIEW v WHERE 1=1 ';
    IF @LocationId is not null
    begin
        set @sql = @sql + ' AND v.LocationId = ''' + @LocationId + '''';
    end
    if @userName is not null
    begin
        set @sql = @sql + ' AND (v.FirstUser = '' OR v.SecondUser = '')' + @userName + '''';
    end
    if @startDate is not null 
    begin
       set @sql = @sql + ' AND v.FirstVisitDate = ''' + @startDate + ''''; 
    end
    if @endDate is not null 
    begin
        set @sql = @sql + ' AND v.LastVisitDate = ''' + @endDate + ''''; 
    end

    EXEC(@sql)

I get both the LocationId and userName from a VS2010 application.
Thanks in Advance

Answer 1

When appending strings together in SQL Server, you have to cast non-textual types (such as int) to a textual type (such as varchar):

set @sql = @sql + ' AND v.LocationId = ''' +
    cast(@LocationId as varchar(10)) + '''';
--  ^^^^ have to cast           ^^ make sure size is big enough

Note that dynamic SQL should not be necessary in the first place. You can just run the query directly with the parameters (I implemented the null checks with the extra or conditions):

SELECT * FROM VW_MASTERVIEW v
 WHERE (v.LocationId = @LocationId    OR @LocationId is null)
   AND (v.FirstUser = @userName OR v.Seconduser = @userName OR @userName is null)
   AND (v.FirstVisitDate = @startDate OR @startDate is null)
   AND (v.LastVisitDate = @endDate    OR @endDate is null)

I may not have the logic right for FirstUser and SecondUser – I took an educated guess from your incomplete code.

Hope this helps!