Question

Want to change this piece of SQL query into a loop version which
Could Select-Insert records by 1000 items per iteration.

On each iteration want to get a print to see what was the last inserted item.

The Code :

INSERT INTO [tData2]
(
    [Key], 
    Info1,
    Info2
)
SELECT 
    [Key], --the Id
    Info1,
    Info2
FROM
    [tData]

Edit :

(There were other conditions to limit the insertion, which aren’t related to the question)

The Bulk-Insertion logic will not be changed, just we shrink the database pieces to be inserted.
Instead of inserting the whole table we Bulk-Insert 10000 items per iteration and could get a simple report on it also.

your help is really appreciated.

Answer 1

Here’s some sample code I quickly put together for you to experiment with. This doesn’t use a cursor (uses while instead) but you could build it that way as well. There are some performance optimizations that you could make but only you can judge that. YMMV

    set nocount on

/* mock up source/dest tables */
declare @src table (id int, value varchar(max));
declare @dest table (id int, value varchar(max));

/* fill source with some data */
declare @rownum int;
set @rownum=0;
while (@rownum<5000) begin
    insert into @src select @rownum,'test value ' + CONVERT(varchar(25),@rownum);
    select @rownum=@rownum+1;
end

/* laod batched data */
declare @pagesize int;set @pagesize=1000;
declare @rowlow int;set @rowlow=0;
declare @rowmax int;set @rowmax=@pagesize;

declare @ct int;select @ct = COUNT(*) from @src;
declare @id int;
declare @value varchar(max);

while (@rowmax<=@ct) begin

    WITH result_set AS (
      SELECT ROW_NUMBER() OVER (ORDER BY id) AS [row_number], id,value
      FROM @src  
    ) insert into @dest 
        SELECT id,value FROM result_set
        WHERE [row_number] BETWEEN @rowlow AND @rowmax

    -- Output
    print 'Copied rows ' + convert(varchar(25),@rowlow) + ' to ' + convert(varchar(25),@rowmax)     

    -- Increment batch counters
    select @rowlow=@rowmax+1,@rowmax+=@pagesize;
end

select * from @dest