Question

We are currently calling web services on our application server through our web server using asp/vbscript. This works very well during low load. However during high load it can sometimes take up to 25 seconds to execute a query like below:

Public Function GetValidLogon(storeKey, username)
    Dim req
    Set req = CreateObject("Microsoft.XMLHTTP")

    Dim soapReq
    soapReq = "<?xml version=""1.0"" encoding=""utf-8""?> " + _
                "<soap:Envelope " + _
                    "xmlns:soap=""http://schemas.xmlsoap.org/soap/envelope/"" " + _
                    "xmlns:xsi=""http://www.w3.org/2001/XMLSchema-instance"" " + _
                    "xmlns:xsd=""http://www.w3.org/2001/XMLSchema""> " + _
                    "<soap:Body> " + _
                        "<GetValidLogon xmlns=""" + namespace + """> " + _ 
                            "<storeKey>" + _
                                CStr(storeKey) + _
                            "</storeKey>" + _
                            "<username>" + _
                                CStr(username) + _
                            "</username>" + _
                        "</GetValidLogon> " + _
                    "</soap:Body> " + _
                "</soap:Envelope>"

    req.open "POST", Me.serviceAddress, False
    req.setRequestHeader "Content-Type", "text/xml; charset=utf-8"
    req.setRequestHeader "SOAPAction", Me.serviceNamespace + "GetValidLogon"
    req.send soapReq

    Set GetValidLogon = SOAPResponseTo_GetValidLogonOutput(req.responseText)
End Function

What do you think might be the issue? Is it the code we are using to call the web services(see above) or is it just the fact that we are using vbscript/asp to call web the web services? Can it be some settings in IIS…?

And every time, even during high load it’s always fast when we are executing the web service directly on the application server.

Answer 1

Never use

CreateObject("Microsoft.XMLHTTP")

in server side applications.. use

CreateObject("MSXML2.ServerXMLHTTP")

instead.