Question

We are working on an internal inventory system. When a user orders and item from a vendor and puts in the order information, I want the users input of brand, model, SKU, etc to be free form input, then when submitted, it compares all of those values to items already in the inventory database. First it would compare the SKU if found then its a direct match. If not, then it moves on to comparing model and brand and asks the user to confirm they are the same item.

Does anyone have any ideas on best methods for accomplishing this? I cant even think of what this would be called to google it.
Code examples / resources would be appreciated!

Answer 1

Assume your form field is named “orderInfo”, and has the value “12345 Acme Gadget” (where 12345 is a valid SKU)

<cfquery name="checkSKU" datasource="inventoryDSN">
SELECT 
 * 
FROM 
 Inventory 
WHERE 
 cast(SKU as varchar) IN (<cfqueryparam value="#ListChangeDelims(form.orderInfo, ' ', ',')#" list="true" cfsqltype="cf_sql_varchar">)
</cfquery>

<cfif checkSKU.recordCount>
  <!--- We have a match! --->
<cfelse>

<cfquery name="checkOthers" datasource="inventoryDSN">
SELECT 
 inventory.*
FROM 
 Inventory 
WHERE 
 1=0
 <cfloop list="#form.orderInfo#" delimiters=" " index="searchTerm">
OR brand LIKE <cfqueryparam value="%#searchTerm#%" cfsqltype="cf_sql_varchar">
OR model LIKE <cfqueryparam value="%#searchTerm#%" cfsqltype="cf_sql_varchar">
</cfloop>
</cfquery>

<cfif checkOthers.recordCount IS 1>
  <!--- have a solid match --->
<cfelseif checkOthers.recordCount GT 1>
  <!--- have some ambiguity, present user with choice among returned results --->
<cfelse>
  <!--- No match found, return error message --->
</cfif>