Question

we can set order option of trigger to first, last or none by use sp_settriggerorder command. I want to know what’s significance of set trigger order. and when necessity using this option?

I use SQL Server 2008 R2.

Answer 1

One purpose would be if you want one trigger to perform some form of sanity checks before other triggers (which may have expensive actions) fire. If the first trigger causes a ROLLBACK to occur, the other triggers aren’t fired:

create table T (
    ID int not null
)
go
create trigger T1
on T
after insert
as
    RAISERROR('T1',10,1) WITH NOWAIT
go
create trigger T2
on T
after insert
as
    RAISERROR('T2',10,1) WITH NOWAIT
go
create trigger T3
on T
after insert
as
    RAISERROR('T3',10,1) WITH NOWAIT
go
sp_settriggerorder 'T1','First','Insert'
go
sp_settriggerorder 'T3','Last','Insert'
go
insert into T(ID) values (1)
--T1
--T2
--T3

--(1 row(s) affected)
go
alter trigger T1
on T
after insert
as
    RAISERROR('T1',10,1) WITH NOWAIT
    ROLLBACK TRANSACTION
go
insert into T(ID) values (2)
--T1
--Msg 3609, Level 16, State 1, Line 1
--The transaction ended in the trigger. The batch has been aborted.