Question

We have multi user frontend/backend MS Access 2010 application. We added a process that will close remote frontends when we want to do work on backend such as compact and repair. This is timer based check on table field that if has certain value will close the application.

I do two checks to see if users are connected to database:

• i have login/logout process and can see who is still logged in (its form based so is fallible eg they close form but frontend is still open).

• i used .ldb file viewer to see if anything is still connected

Two questions:

• is there any possibility that a connection to backed could exist if it wasn’t viewable with ldb viewer?

• is there any bullet proof 100% certain way to forcefully disconnect all connections from backend?

Answer 1

“I do two checks to see if users are connected to database“

If you need to open the db exclusively, you can skip the other checks and just check whether you can do it.

Public Function CheckExclusive(ByVal pFullPath As String) As Boolean
    Dim blnReturn As Boolean
    Dim cn As Object
    Dim strConnection As String

On Error GoTo ErrorHandler

    strConnection = "Provider=" & _
        CurrentProject.Connection.Provider & _
        ";Data Source=" & pFullPath & ";"
    Set cn = CreateObject("ADODB.Connection")
    cn.Mode = 12& ' adModeShareExclusive '
    cn.Open strConnection
    blnReturn = True
    cn.Close

ExitHere:
    On Error Resume Next
    Set cn = Nothing
    On Error GoTo 0
    CheckExclusive = blnReturn
    Exit Function

ErrorHandler:
    blnReturn = False
    GoTo ExitHere
End Function

Then call that function with the full path to your db file.

If CheckExclusive("C:\SomeFolder\YourDb.mdb") = True Then
    ' do what you need here which requires exclusive access: '
    '     make backup; compact; whatever '
End If