What are the practical diffences between s and sf in the two code samples below?
I understand that stack relative look like Mem[SP + OprndSpec] and deffered look like Mem[Mem[SP + OprndSpec]]. However what I don’t understand is how this is accomplished.
Stack deffered
BR main
a: .BLOCK 2 ;global variable #2d
b: .BLOCK 2 ;global variable #2d
;
;******* void swap (int& r, int& s)
r: .EQUATE 6 ;formal parameter #2h
s: .EQUATE 4 ;formal parameter #2h
temp: .EQUATE 0 ;local variable #2d
swap: SUBSP 2,i ;allocate #temp
LDA r,sf ;temp = r
STA temp,s
LDA s,sf ;r = s
STA r,sf
LDA temp,s ;s = temp
STA s,sf
RET2 ;deallocate #temp, pop retAddr
;
;******* void order (int& x, int& y)
x: .EQUATE 4 ;formal parameter #2h
y: .EQUATE 2 ;formal parameter #2h
order: LDA x,sf ;if (x > y)
CPA y,sf
BRLE endIf
LDA x,s ; push x
STA -2,s
LDA y,s ; push y
STA -4,s
SUBSP 4,i ; push #r #s
CALL swap ; swap (x, y)
ADDSP 4,i ; pop #s #r
endIf: RET0 ;pop retAddr
;
;******* main ()
main: STRO msg1,d ;cout << "Enter an integer: "
DECI a,d ;cin >> a
STRO msg1,d ;cout << "Enter an integer: "
DECI b,d ;cin >> b
LDA a,i ;push the address of a
STA -2,s
LDA b,i ;push the address of b
STA -4,s
SUBSP 4,i ;push #x #y
CALL order ;order (a, b)
ra1: ADDSP 4,i ;pop #y #x
STRO msg2,d ;cout << "Ordered they are: "
DECO a,d ; << a
STRO msg3,d ; << ", "
DECO b,d ; << b
CHARO '\n',i ; << endl
STOP
msg1: .ASCII "Enter an integer: \x00"
msg2: .ASCII "Ordered they are: \x00"
msg3: .ASCII ", \x00"
.END
Stack relative
BR main
;
;******* int binomCoeff (int n, int k)
retVal: .EQUATE 10 ;returned value #2d
n: .EQUATE 8 ;formal parameter #2d
k: .EQUATE 6 ;formal parameter #2d
y1: .EQUATE 2 ;local variable #2d
y2: .EQUATE 0 ;local variable #2d
binCoeff:SUBSP 4,i ;allocate #y1 #y2
if: LDA k,s ;if ((k == 0)
BREQ then
LDA n,s ;|| (n == k))
CPA k,s
BRNE else
then: LDA 1,i ;return 1
STA retVal,s
RET4 ;deallocate #y2 #y1, pop retAddr
else: LDA n,s ;push n - 1
SUBA 1,i
STA -4,s
LDA k,s ;push k
STA -6,s
SUBSP 6,i ;push #retVal #n #k
CALL binCoeff
ra2: ADDSP 6,i ;pop #k #n #retVal
LDA -2,s ;y1 = binomCoeff (n - 1, k)
STA y1,s
LDA n,s ;push n - 1
SUBA 1,i
STA -4,s
LDA k,s ;push k - 1
SUBA 1,i
STA -6,s
SUBSP 6,i ;push #retVal #n #k
CALL binCoeff
ra3: ADDSP 6,i ;pop #k #n #retVal
LDA -2,s ;y2 = binomCoeff (n - 1, k - 1)
STA y2,s
LDA y1,s ;return y1 + y2
ADDA y2,s
STA retVal,s
endIf: RET4 ;deallocate #y2 #y1, pop retAddr
;
;******* main ()
main: STRO msg,d ;cout << "binCoeff (3, 1) = "
LDA 3,i ;push 3
STA -4,s
LDA 1,i ;push 1
STA -6,s
SUBSP 6,i ;push #retVal #n #k
CALL binCoeff
ra1: ADDSP 6,i ;pop #k #n #retVal
DECO -2,s ;<< binCoeff (3, 1)
CHARO '\n',i ;cout << endl
STOP
msg: .ASCII "binCoeff (3, 1) = \x00"
.END
Your question seems simple and has little to do with code other than they presumably contain examples.
(I’m not familiar with this instruction set, but have been coding a long time in assembly.)
According to the definition you provided, “stack relative” means taking an item from memory at a location determined by the stack pointer, plus a constant offset presumably embedded in an instruction. This is called indexed addressing by most folk, with the special note that it is stack-pointer indexed.
“Deferred” (an old term) usually means “indirect through a memory location” and your definition of that is consistent with this idea: find the “stack relative” location, read that, and use that value as the memory location to fetch.