Question

what is the correct query to select the the “Abstract” Node which is implemented by XYZImpl from http://www.namspace.org/impl?

<...>
  <Abstract xmlns:q3="http://www.namspace.org/impl"
                xsi:type="q3:XYZImpl">
    <...></...>
  </Abstract>
  <Abstract xmlns:q8="http://www.namspace.org/another"
                xsi:type="q8:XYZImpl">
    <...></...>
  </Abstract>
 </...>

order and namespace prefix are not under my control

If the document just contains unique implementations the following query “works”:

//Abstract[contains(@xsi:type,'XYZImpl')]

but I am searching for the right specification for the full qualified Name (namespace + Name)… :/

Answer 1

Use:

   /*/Abstract
       [substring-after(@xsi:type, ':') = 'XYZImpl']
          [namespace::*
              [name() = substring-before(../@xsi:type, ':')
              and
               . = 'http://www.namspace.org/impl'
              ]
          ]

This selects any Abstract child of the top element of the XML document that has a namespace with a prefix, which is also the prefix of the QName value contained in its xsi:type attribute. And the “local-name” part of the QName value contained in the xsi:type attribute is exactly the string "XYZImpl" .

XSLT – based verification:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xsi="some:xsi">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/">
     <xsl:copy-of select=
      "/*/Abstract
           [substring-after(@xsi:type, ':') = 'XYZImpl']
              [namespace::*
                  [name() = substring-before(../@xsi:type, ':')
                  and
                   . = 'http://www.namspace.org/impl'
                  ]
              ]
      "/>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the following XML document (produced by the provide, by making it well-formed):

<t xmlns:xsi="some:xsi">
      <Abstract xmlns:q3="http://www.namspace.org/impl"
                    xsi:type="q3:XYZImpl">
       </Abstract>
      <Abstract xmlns:q8="http://www.namspace.org/another"
                    xsi:type="q8:XYZImpl">
      </Abstract>
</t>

the wanted, correct element is selected and copied to the output:

<Abstract xmlns:q3="http://www.namspace.org/impl" xmlns:xsi="some:xsi" xsi:type="q3:XYZImpl"/>

Do note: In order for the XPath expression to be evaluated successfully, the appropriate namespace with prefix xsi must be registered with your XPath implementation.