Question

When compiling this:

data Rec t = Rec { intPt :: t Int, doublePt :: t Double } deriving Show

type Pt2 a = (a,a)
type Pt3 a = (a,a,a)

type Rec2 = Rec Pt2 
type Rec3 = Rec Pt3

main = do
      print $ Rec (1,2) (3.4,5.6)
      print $ Rec (1,2,3) (5.6, 7.8, 9.0)   

I got

Unexpected type `t a' where type variable expected
In the declaration of `Rec (t a)'

How to make this compile and work?

Answer 1

I cannot reproduce the exact error message you’re reporting, but I can see two issues with your example.

1. You are trying to derive Show for Rec which is parameterized over a type constructor. This is too hard for GHC to do fully automatically at the moment, but you can make it work in practice by enabling a number of extensions.

2. You are using partially applied type synonyms Pt2 and Pt3 as arguments to Rec, which isn’t permitted. You can work around this by switching to datatypes.

A bit more detail: To solve problem 1, you can say:

{-# LANGUAGE StandaloneDeriving, FlexibleContexts, UndecidableInstances #-}

data Rec t = Rec { intPt :: t Int, doublePt :: t Double }
deriving instance (Show (t Int), Show (t Double)) => Show (Rec t)

By using a standalone deriving clause, you can explicitly specify the preconditions on the Show instance. In this case, these preconditions require the FlexibleContexts and UndecidableInstances extensions to also be enabled.

To solve problem 2, you can do the following:

data Pt2 a = Pt2 a a deriving Show
data Pt3 a = Pt3 a a a deriving Show

type Rec2 = Rec Pt2 
type Rec3 = Rec Pt3

Datatypes can be partially applied, but type synonyms cannot. So using Pt2 as an argument to Rec is only allowed if Pt2 is a datatype. With these modifications, your main function typechecks (and works):

main = do
  print $ Rec (Pt2 1 2) (Pt2 3.4 5.6)
  print $ Rec (Pt3 1 2 3) (Pt3 5.6 7.8 9.0)