Question

While transforming a document, I need to ‘look up’ certain node contents in a ‘map’, and write those values.

I inlined my ‘map’ in the transformation.

<xsl:variable name="inlinedmap">
    <kat id="stuff">value</kat>
    <!-- ... -->
</xsl:variable>
<xsl:variable name="map" select="document('')/xsl:stylesheet/xsl:variable[@name='inlinedmap']" />
<xsl:template match="/">
    <xsl:for-each select="/*/foo">
        <!-- 'bar' contents should equal to contents of 'kat' -->
        <xsl:variable name="g" select="$map/key[.=bar]"/>
        <xsl:choose>
            <xsl:when test="$g != ''">
                <xsl:value-of select="$g/@id"/>
            </xsl:when>
            <xsl:otherwise>
                ERROR
            </xsl:otherwise>
        </xsl:choose>
    </xsl:for-each>
</xsl:template>

I’m always getting ERROR value.
I can’t put map value’s into attributes, because they contain letters that get escaped.

How can I make it work?

Answer 1

I think there are a few problems here:

• You seem to be looking for key elements in your variable, but they’re called kat there (typo?)
• You seem to be trying to reference the bar child of the context node inside the loop, but you need to use current() to do that
• You should create this map as elements in your own namespace instead of an xsl:variable

Here’s a complete example. This stylesheet:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:my="my">
    <my:vars>
        <kat id="stuff">value</kat>
        <!-- ... -->
    </my:vars>
    <xsl:variable name="map" select="document('')/*/my:vars/*"/>
    <xsl:template match="/">
        <xsl:for-each select="/*/foo">
            <!-- 'bar' contents should equal to contents of 'kat' -->
            <xsl:variable name="g" select="$map[.=current()/bar]"/>
            <xsl:choose>
                <xsl:when test="$g != ''">
                    <xsl:value-of select="$g/@id"/>
                </xsl:when>
                <xsl:otherwise>
                    ERROR
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Applied to this input:

<root>
    <foo><bar>value</bar></foo>
    <foo><bar>value1</bar></foo>
    <foo><bar>value2</bar></foo>
    <foo><bar>value3</bar></foo>
</root>

Produces this output (one match):

stuff
ERROR
ERROR
ERROR