Question

Why does this code still send an email when the condition to link to the email
send cannot get executed? SASLOG proves condition vale is zero put x=.

98   filename outbox email '[e-mail]';
99
100  data _null_;
    /* Set variable */
101     x=0;  
102     put x=;
    /* condition cannot be true */
103     if x=1 then do;  
104        link send_email;  /* should only be hit if condition is true */
105     end;
106  return;
107
108  send_email:  /* seems to get executed no matter what */
109     file outbox
110     to=("dan.xxxxx@zzcom")
111     subject="Email test";
112     put "Email test from SAS program";
113     put " ";
114  return;
115  run;

NOTE: The file OUTBOX is:
      E-Mail Access Device

x=0
Message sent
      To:          ("[e-mail]" )
      Cc:
      Bcc:
      Subject:     Email test
      Attachments:
NOTE: 0 records were written to the file OUTBOX.
NOTE: DATA statement used (Total process time):
      real time           7.22 seconds
      cpu time            0.35 seconds

Answer 1

Without more background it’s hard to guess exactly how you are planning to do this but I think a cleaner approach would be to:

1. Identify if an email should be sent.
2. Use a datastep within macro code to conditionally send the email.

Step 1:

%let send_email = 0;  * WHEN 0 EMAIL WILL NOT BE SENT. WHEN 1 EMAIL WILL BE SENT;

data _null_;
  set mydata;
  if x = 1 then do;
    call symput('send_email',1);
    stop; * LEAVE THE DATASTEP AS SOON AS WE DECIDE AN EMAIL SHOULD BE SENT;
  end;
run;

Step 2:

%macro send_email;
  %if &send_email eq 1 %then %do;
    filename outbox email '[e-mail]';
    data _null_;
      file outbox to=("dan.xxxxx@zzcom") subject="Email test";
      put "Email test from SAS program";
      put " ";
    run;
  %end;
%mend;
%send_email;

EDIT: Changed return statement in the code to a stop statement.