Question

Within a Chrome extension, how can I inject items into the context menus of 3rd party flash objects?

Is it possible to simply inject items using JavaScript?

Is it possible to wrap the players in a container .swf that adds our context menu item along with the items included by the original swf?

Thanks so much for your ideas and inspiration!

Edit: To be clear, what I’d like to do with my extension is add a context menu item to any 3rd party Flash program. So for instance, if a user visits YouTube, I’d like to add my own menu item along with YouTube’s custom items.

Answer 1

The easiest solution is to do exactly what you and @felipemaia suggested – make use of a loader SWF that adds (or modifies) the context menu of its loaded SWF.

The original (loaded) SWF:

import flash.ui.ContextMenu;
import flash.ui.ContextMenuItem;

var customContextMenu:ContextMenu = new ContextMenu();
// Comment in if you want to hide the default context menu items.
// customContextMenu.hideBuiltInItems();
var sampleItem:ContextMenuItem = new ContextMenuItem('Cheerio!');
customContextMenu.customItems.push(sampleItem, new ContextMenuItem('What it do?'));
this.contextMenu = customContextMenu;

And the loader SWF:

import flash.ui.ContextMenu;
import flash.ui.ContextMenuItem;
import flash.display.Sprite;
import flash.display.Loader;
import flash.net.URLRequest;
import flash.events.Event;

var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, modify_context_menu);
loader.load(new URLRequest('LoadedSWF.swf'));

function modify_context_menu(event:Event):void
{
    var loadedSWF:Sprite = (event.target as LoaderInfo).content as Sprite;  
    var loadedContextMenu:ContextMenu = loadedSWF.contextMenu;  
    loadedContextMenu.customItems.push(new ContextMenuItem('Parent Menu Item'), new ContextMenuItem('Parent what it be?'));

    this.contextMenu = loadedContextMenu;
}

Note that if you need finer grain control you can also modify the context menu on individual InteractiveObject subclasses:

var sprite:Sprite = new Sprite();
var spriteContextMenu:ContextMenu = new ContextMenu();
spriteContextMenu.customItems.push(new ContextMenuItem('Instance specific menu item!'));
sprite.contextMenu = spriteContextMenu;