Question

Consider this simple “benchmark”:

n :: Int
n = 1000
main = do
    print $ length [(a,b,c) | a<-[1..n],b<-[1..n],c<-[1..n],a^2+b^2==c^2]

and appropriate C version:

#include <stdio.h>

int main(void)
{
    int a,b,c, N=1000;
    int cnt = 0;

    for (a=1;a<=N;a++)
        for (b=1;b<=N;b++)
            for (c=1;c<=N;c++)
                if (a*a+b*b==c*c) cnt++;
    printf("%d\n", cnt);
}

Compilation:

• Haskell version is compiled as: ghc -O2 triangle.hs (ghc 7.4.1)
• C version is compiled as: gcc -O2 -o triangle-c triangle.c (gcc 4.6.3)

Run times:

• Haskell: 4.308s real
• C: 1.145s real

Is it OK behavior even for such a simple and maybe well optimizable program that Haskell is almost 4 times slower? Where does Haskell waste time?

Answer 1

The Haskell version is wasting time allocating boxed integers and tuples.

You can verify this by for example running the haskell program with the flags +RTS -s. For me the outputted statistics include:

  80,371,600 bytes allocated in the heap

A straightforward encoding of the C version is faster since the compiler can use unboxed integers and skip allocating tuples:

n :: Int
n = 1000
main = do
  print $ f n

f :: Int -> Int
f max = go 0 1 1 1
  where go cnt a b c
          | a > max = cnt
          | b > max = go cnt (a+1) 1 1
          | c > max = go cnt a (b+1) 1
          | a^2+b^2==c^2 = go (cnt+1) a b (c+1)
          | otherwise = go cnt a b (c+1)

See:

  51,728 bytes allocated in the heap

The running time of this version is 1.920s vs. 1.212s for the C version.