Question

Hi below is the data sample for chart data which I read from URL

ARRAY ‘ ‘ 3 8

Y

25 75 100 125 150 175 200 225

‘A’ 3 8 6 7 5 3 2 7

‘B’ 1 9 7 8 4 7 2 5

‘C’ 8 7 3 6 56 9 111 8

Now in this I want to save this data into a csv file as below

Time    A   B   c
25      3   1   8
75      8   9   7
100     6   7   3
125     7   8   9
150     5   4   56
175     3   7   9
200     2   2   111
225     7   5   8

Actually I have to first read the data into an array in which each element will contain one line of the data file, Now I will have to split the each element by space and store it in a two dimensional array, now for each ith index of each array I have to create a coma separated line then put “\n” at the end of line , and at last save this to a csv file .

I don’t know much about the syntax of vb-script and classic asp that’s why I am facing this problem . Please help me

Answer 1

To get you started:

Sub doReOrder(sFSpecI, sFSpecO, sCol1)
  Dim oTS    : Set oTS = goFS.OpenTextFile(sFSpecI)
  Dim sData  : sData   = oTS.ReadLine() ' ARRAY ' ' 3 8
  Dim aParts : aParts  = Split(sData, " ")
  Dim nCols  : nCols   = CByte(aParts(3)) ' Count vs UBound vs Data!
  Dim nRows  : nRows   = CByte(aParts(4))
  Dim nRows2 : nRows2  = nRows + 1
  oTS.SkipLine ' Y
  ' get table in one string, prepend col1 name, clean '
  sData  = "'" & sCol1 & "' " & Replace(oTS.ReadAll(), vbCrLf, " ")
  sData  = Trim(Replace(sData, "'", """"))
  ' get table in flat array
  aParts = Split(sData, " ")
  oTS.Close
  Set oTS = goFS.CreateTextFile(sFSpecO, True)
' WScript.Echo Join(aParts, "|")
  ReDim aData(nCols) ' hold one (new) row to prep for Join
  Dim nRow
  For nRow = 0 To nRows
      Dim nCol
      For nCol = 0 To nCols
          ' magic column hopping
          aData(nCol) = aParts(nRow + nCol * nRows2)
      Next
      oTS.WriteLine Join(aData, ",")
  Next
  oTS.Close
End Sub

Test:

  Dim sFSpecI : sFSpecI = "..\Data\f1.txt"
  Dim sFSpecO : sFSpecO = "..\Data\f1.csv"
  Dim sCol1   : sCol1   = "Time" ' dangerous - possibly reserved in SQL
  WScript.Echo goFS.OpenTextFile(sFSpecI).ReadAll()
  doReOrder sFSpecI, sFSpecO, sCol1
  WScript.Echo goFS.OpenTextFile(sFSpecO).ReadAll()

Output:

ARRAY ' ' 3 8
Y
25 75 100 125 150 175 200 225
'A' 3 8 6 7 5 3 2 7
'B' 1 9 7 8 4 7 2 5
'C' 8 7 3 6 56 9 111 8

"Time","A","B","C"
25,3,1,8
75,8,9,7
100,6,7,3
125,7,8,6
150,5,4,56
175,3,7,9
200,2,2,111
225,7,5,8