Question

I am trying to create an array of arrays in Fortran.

Something like the following

TYPE :: array_of_arrays
   REAL, DIMENSION(:), POINTER :: p => NULL()
END TYPE

TYPE(array_of_arrays), DIMENSION(2) :: some_array

So that I can do:

REAL, DIMENSION(3), TARGET :: some_vector1 = (/1.0, 2.1, 4.3/)
REAL, DIMENSION(3), TARGET :: some_vector2 = (/3.0, 1.2, 9.6/)

some_array(1)%p => some_vector1
some_array(2)%p => some_vector2

WRITE(*,*) some_array(1)%p ! I see some_vector1
WRITE(*,*) some_array(2)%p ! I see some_vector2

Now it’s cumbersome for me to actually declare each of these some_vector arrays to correspond to each element in my array of arrays.

What I’d like to do is have in a separate subroutine where a temporary vector is set as a target, and that subroutine sets up my array of arrays to point to that temporary vector.

This way I can have anonymous arrays.

However, this doesn’t seem to be working and I wonder if first if I am doing something that Fortran doesn’t support.

So does Fortran support anonymous arrays, that is (in case I have the terms wrong), an array who can only be accessed through a reference?

Answer 1

Sure; as IanH suggests, you can just have the pointer refer to allocated memory directly, rather than refer to a variable; this is one of the few cases where the allocated memory doesn’t automatically get deallocated once it goes out of scope.

eg,

module arrays


TYPE :: array_of_arrays
   REAL, DIMENSION(:), POINTER :: p => NULL()
END TYPE

contains

subroutine alloc(aa)
    type(array_of_arrays), intent(inout) :: aa(:)
    integer :: i

    allocate( aa(1)%p(1) )
    aa(1) % p = [1.]

    allocate( aa(2)%p(5) )
    aa(2) % p = [ (i, i=1,5) ]

end subroutine alloc

end module arrays



program usearrays
    use arrays

    TYPE(array_of_arrays), DIMENSION(2) :: some_array

    call alloc(some_array)

    WRITE(*,*) some_array(1)%p ! I see some_vector1
    WRITE(*,*) some_array(2)%p ! I see some_vector2

    deallocate( some_array(1) )
    deallocate( some_array(2) )

end program usearrays

and running it gives

$ gfortran -o arrays arrays.f90 
$ ./arrays 
   1.0000000    
   1.0000000       2.0000000       3.0000000       4.0000000       5.0000000