Question

I am trying to run an application inside a Perl script using system(). The application I’m running gets stuck sometimes (it enters some kind of infinite loop). Is there a way I can know if this application is stuck and kill it to continue with the Perl script?

I’m trying to do something like this:

start testapp.exe;
if(stuck with testapp.exe) {
    kill testapp.exe;
}

Answer 1

Determining if “it is stuck in infinite loop” is called Halting Problem and is undecidable.

If you want to kill it, you will have to fork the application using fork and then kill it from the other fork, if it is going for too long.

You can determine if the proccess is going for too long by this

use POSIX ":sys_wait_h";
waitpid($pid, WNOHANG)>0 #waitpid returns 0 if it still running

at least, according to this manual page

I am not sure how well it works on various systems, you can try it out.

Not a direct answer, but I can recommend using forks module if you want to fork with ease, but it works only on UNIX systems (not windows).

---

OK, more helping code 🙂 It works in UNIX, according to perlfork perldoc, it should work on Windows exactly the same way.

use warnings;
use strict;

use POSIX ":sys_wait_h";
my $exited_cleanly;                 #to this variable I will save the info about exiting

my $pid = fork;
if (!$pid) {
     system("anything_long.exe");        #your long program 
} else {
     sleep 10;                           #wait 10 seconds (can be longer)
     my $result = waitpid(-1, WNOHANG);  #here will be the result

     if ($result==0) {                   #system is still running
         $exited_cleanly = 0;            #I already know I had to kill it
         kill('TERM', $pid);             #kill it with TERM ("cleaner") first
         sleep(1);                       #wait a bit if it ends
         my $result_term = waitpid(-1, WNOHANG);
                                         #did it end?

         if ($result_term == 0) {        #if it still didnt...
             kill('KILL', $pid);         #kill it with full force!
         }  
     } else {
         $exited_cleanly = 1;            #it exited cleanly
     }  
}

#you can now say something to the user, for example
if (!$exited_cleanly) {...}