Question

i extend ArrayCollection class for add push method

package com.cargo.collections
{
    import mx.collections.ArrayCollection;

    public class DataCollection extends ArrayCollection {

        public function DataCollection(source:Array = null) {
            super(source);
        }

        public function push(...parameters):uint {
            var i:uint = source.push(parameters);
            this.refresh();
            return i;
        }
    }
}

but pushed data is array :/

var test:DataCollection = new DataCollection({id: 1});
test.source.push({id: 2});
test.push({id: 3});

output is

test = Array( {id: 1}, {id: 2}, Array({id: 3}) )

Answer 1

In your example ...parameters creates an array containing all the arguments passed to that function. This should work as expected:

public function push(...parameters):uint {
    var i:uint = source.push(parameters[0]);
    this.refresh();
    return i;
}

Alternatively, if your purpose is to enable the pushing of multiple parameters you can use the Function.apply() method, which will translate a given array into multiple parameters:

public function push(...parameters):uint {
    var i:uint = source.push.apply(null,parameters);
    this.refresh();
    return i;
}

This is the equivalent of saying

var i:uint = source.push(parameters[0],parameters[1],parameters[2]);  // etc