Question

I have 2 worksheets, I need to update with data from another worksheet I receive every week. I wonder if its possible
to copy the data into the excel file with the 2 worksheets I need updating and then run a macro that selects the cells i need to output to the other worksheets.
I don’t know if i am being clear enough, below is an example.

For example I have the following sheet, I need to look though the “name” column and if the name begins with “sony”, copy the cells i need to the sony worksheet, if it begins with Samsung copy the cells i need to the Samsung sheet and so on.

I suppose that copying the whole row then deleting the columns I don’t need will also work.

Main Sheet Example

Name            --- Type --- Extra --- Year --- Power

Sony TV         --- LCD  --- CAM   --- 2009 --- 90W

Samsung TV      --- LED  --- WIFI   --- 2010 --- 70W

Sony TV         --- LCD  --- SAT   --- 2011 --- 90W

Hitachi TV      --- LED  --- CAM   --- 2012  --- 70W 

Sony Sheet Example

Name   --- Type  --- Year --- Power 
Samsung sheet Example

Name   --- Type  --- Year --- Power 

Answer 1

I would use an AUTOFILTER on column A to get just the rows I want visible, then we can copy just the columns we want. In this example, the shtARR is used for both the sheetnames and the filter, so make your target sheet names match, Sony, Samsung, Hitachi, etc. Then try this:

Sub VendorFilters()
Dim ws2 As Worksheet, LR As Long
Dim shtARR As Variant, i As Long

'assuming these are the names of the target sheets, we can use for filtering, too
shtARR = Array("Sony", "Samsung", "Hitachi")

With Sheets("Main")                 'filtering the sheet with the original data
    .AutoFilterMode = False         'turn off any prior filters
    .Rows(1).AutoFilter             'new filter

    For i = LBound(shtARR) To UBound(shtARR)
        Set ws2 = Sheets(shtARR(i))         'if you get an error here, check the sheet names

        .Rows(1).AutoFilter 1, shtARR(i) & "*"          'new filter for current value
        LR = .Range("A" & .Rows.Count).End(xlUp).Row    'last row with visible data

        If LR > 1 Then                  'if any rows visible, copy wanted columns to sheet2
            .Range("A2:A" & LR).Copy ws2.Range("A1")
            .Range("C2:D" & LR).Copy ws2.Range("B1")
        End If
    Next i

    .AutoFilterMode = False             'remove the filter
End With

End Sub

Autofilters are nice, they allow you to avoid looping row by row, but it means you can’t have blank rows in the data. Sort the data before to remove the blanks, if present.