Question

i have a macro (Makro1) that is assigned to a button in a custom toolbar (Custom1) with caption “Schutzstatus”. i want the toolbar only to be loaded with this very xls-file.

can someone help me out with the code?

i managed to customize the tooltip:

Application.CommandBars("Custom1").Controls(1).TooltipText = "Abfrage des Schutzstatus der Arten im Zwischenspeicher"

but i fail in creating the whole thing by vba..

thanks in advance,
kay

Answer 1

You don’t actually need to (re)create the whole toolbar on loading your XLS, but you need to display/hide it during certain navigations

1 create the toolbar

2 attach it to your XLS (view / toolbars / customize …. / attach)

3 create event procedures to show/hide your toolbar; unless you want to have a specific behaviour for different sheets, the following should be enough to care for all navigation:

Private Sub Workbook_Activate()
    ' show toolbar
    Application.CommandBars("CoolBar").Visible = True
    Application.CommandBars("CoolBar").Controls(1).TooltipText = "C'mon squeeze me"
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    ' drop toolbar
    Application.CommandBars("CoolBar").Delete
End Sub

Private Sub Workbook_Deactivate()
' see if we have a toolbar (it might have been already deleted by "Workbook_BeforeClose"
' if yes - hide it
Dim Idx As Integer

    For Idx = 1 To Application.CommandBars.Count
        If Application.CommandBars(Idx).Name = "CoolBar" Then
            Application.CommandBars("CoolBar").Visible = False
        End If
    Next Idx
End Sub

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
' display toolbar
    Application.CommandBars("CoolBar").Visible = True
End Sub

Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
    Application.CommandBars("CoolBar").Visible = False
End Sub

Place all in the “ThisWorkbook” object – so they fire on all sheets.

4 After saving the toolbar with the XLS and testing, close the XLS – the toolbar will be still present in your application object – and delete the toolbar from there. Don’t panic, it’s coming back when you re-open your XLS file.

Hope this helps
Tschüss MikeD