Question

I have a problem with the script I wrote:

@echo off 
e:
cd folder1
cd logs
cd App1

for /F "skip=20 delims=" %%F in ('dir /b/o-d/a-d log11101*.*') do del "%%F"

The script works well for 1 folder. It keeps the 20 latest log files, and delete all the rest of the files starting with “log11101” in the folder (because I have other log files in these folder I do not want to delete with this script…
I want to apply this script in multiple folders, but that are all in FOLDER1, using the same “for /f “skip=20…………………………….do del “%%F” .
I tought of doing something like this since the parent folder is FOLDER1/LOGS:

@echo off 
e:
cd folder1
cd logs
cd App1

for /F "skip=20 delims=" %%F in ('dir /b/o-d/a-d log11101*.*') do del "%%F"

cd ..
cd App2

for /F "skip=20 delims=" %%F in ('dir /b/o-d/a-d log11101*.*') do del "%%F"

But it doesn’t work ! It works for 1 folder, but the other, it deletes all but 1 file, instead of keeping 20 files and deleting the rest.

Would there be a way for me to put all folders I want to target with the script, something like this and run only this script once ? :

x:/folder1/logs/app1
x:/folder1/logs/app2
x:/folder1/logs/app4

for /f "skip=20...............

Thanks

Answer 1

I don’t see how your 2nd code base only preserves 1 file in the 2nd folder – the 2nd folder should behave identically to the 1st. Are you sure the App2 folder had more than 1 log11101* file to begin with?

Recommendation – insert ECHO before your DEL command and look at the results. Once the output looks correct, then remove the ECHO to make the script functional.

It takes very little code to conveniently perform your delete action on a list of folders that reside in your root:

@echo off
for %%D in ("App1" "App2" "App4") do (
  cd /d "e:\folder1\logs\%%~D"
  for /f "skip=20 delims=" %%F in ('dir /b /o-d /a-d log11101*.*') do echo del "%%F"
)

If you want to perform your delete on all folders within your root:

@echo off
for /d %%D in ("e:\folder1\logs\*") do (
  cd /d "%%D"
  for /f "skip=20 delims=" %%F in ('dir /b /o-d /a-d log11101*.*') do echo del "%%F"
)

I’ve added the ECHO before DEL, so once everything looks good, remove ECHO to make it functional.