Question

I have a spreadsheet, it contains 18 columns.
What I want to do is when doing data entry the tab will move till end of the record, i.e. 18col. Then it goes to the next row 1st col. If user wants to go at middle of the record, it won`t allow.

If it is possible to do through VBA, please help me.

Thanks

Answer 1

If just need to keep the user from selecting outside the desired range (18 columns), you don’t even need VBA. Use sheet protection and don’t allow users to select locked cells. Here’s a quick review of how sheet protection works: http://www.dummies.com/how-to/content/how-to-protect-cell-data-in-excel-2010.html

If you also need to enforce that cells are populated in order, you’ll need to add this VBA code. It uses an event procedure to unlock the “next” cell if the “previous” cell was populated; if it wasn’t, the current cell is moved back to the previous cell so the user can fill it in.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim rngPrev As Range
    Dim rngNext As Range
    Const LAST_COL As Long = 18

    Select Case Target.Column
        Case Is = 1
            If Target.Row > 1 Then
                Set rngPrev = Target.Offset(-1, LAST_COL - 1)
            Else
                Set rngPrev = Target
            End If
            Set rngNext = Target.Offset(0, 1)
        Case 2 To LAST_COL - 1
            Set rngPrev = Target.Offset(0, -1)
            Set rngNext = Target.Offset(0, 1)
        Case 18
            Set rngPrev = Target.Offset(0, -1)
            Set rngNext = Target.Offset(1, 1 - LAST_COL)
    End Select
    If Not IsEmpty(rngPrev.Value) > 0 Then
        Me.Unprotect
        rngNext.Locked = False
        ' note: this line is for testing purposes to show which cells get unlocked
        rngNext.Interior.ColorIndex = 6
        Me.Protect
    Else
        rngPrev.Activate
    End If
End Sub