Question

I have data dumper outputting a remotely hosted xml file into a local text file and I am getting the following info:

$VAR1 = {
    'resource' => {
        '005cd410-41d6-4e3a-a55f-c38732b73a24.xml' => {
            'standard' => 'DITA',
            'area' => 'holding',
            'id' => 'Comp_UKCLRONLINE_UKCLR_2000UKCLR0278',
        },
        '003c2a5e-4af3-4e70-bf8b-382d0b4edda1.xml' => {
            'standard' => 'DITA',
            'area' => 'holding',
            'id' => 'Comp_UKCLRONLINE_UKCLR_2000UKCLR0278',
        },  

etc. What I want to do is work with just one/key and value in each resource. Ie pick out the ID and then create a url from that.

I would normally use a regex on the file and pull the info I need from that but I’m thinking there must be an easier/proper way but can’t think of the right term to use in a search and am therefore not finding it.

Here is the code I am using to write this output to a file:

#-----------------------------------------------
sub request_url {
#-----------------------------------------------
my $useragent = LWP::UserAgent->new;
my $request = HTTP::Request->new( GET => "http://digitalessence.net/resource.xml" );
$resource = $useragent->request( $request );                                            
}


#-----------------------------------------------
sub file_write {
#-----------------------------------------------
open OUT, ">$OUT" or Log_message ("\n$DATE - $TIME - Could not create filelist.doc \t");
Log_message ("\n$DATE - $TIME - Opened the output file");
print OUT Dumper (XML::Simple->new()->XMLin( $resource->content ));
Log_message ("\n$DATE - $TIME - Written the output file");
}

thanks

Answer 1

Maybe you want to walk the data structure built by XML::Simple.
Each resource is inside an ARRAYREF you get using the resource key with $doc data structure.

use XML::Simple;
use LWP;
use Data::Dumper;

my $ua = LWP::UserAgent->new;
my $req = HTTP::Request->new( GET => "http://digitalessence.net/resource.xml" );
my $res = $ua->request( $req );

my $xs         = XML::Simple->new();
my $doc        = $xs->XMLin( $res->content );

printf "resources: %s\n", scalar keys %{ $doc->{ resource } };

foreach ( keys %{ $doc->{ resource } } ) {
    printf "resource => %s, id => %s\n", $_, $doc->{ resource }->{ $_ }->{ id };
}

The output is this:

resources: 7
resource => 005cd410-41d6-4e3a-a55f-c38732b73a24.xml, id => Comp_UKCLRONLINE_UKCLR_2000UKCLR0278
resource => 003c2a5e-4af3-4e70-bf8b-382d0b4edda1.xml, id => Comp_UKCLRONLINE_UKCLR_2002UKCLR0059
resource => 0033d4d3-c397-471f-8cf5-16fb588b0951.xml, id => Comp_UKCLRONLINE_UKCLR_navParentTopic_67
resource => 002a770a-db47-41ef-a8bb-0c8aa45a8de5.xml, id => Comp_UKCLRONLINE_UKCLR_navParentTopic_308
resource => 000fff79-45b8-4ac3-8a57-def971790f16.xml, id => Comp_UKCLRONLINE_UKCLR_2002UKCLR0502
resource => 00493372-c090-4734-9a50-8f5a06489591.xml, id => Comp_UKCLRONLINE_COMPCS_2010_10_0002
resource => 004377bf-8e24-4a69-9411-7c6baca80b87.xml, id => Comp_CLJONLINE_CLJ_2002_01_11