Question

i have the following code:

• It is supposed to go into a sheet named “Flash” and get the i-th 2 digit numeric value and retrieve the value in a column offset 4 to the right of the Activecell.
• Then swap to a sheet named “Sheet1” on the same workbook and use a Vertical Lookup function to find the retrieved value and return the value 4 columns to the right of that cell.

However when i run the script below it stops working at :

MsgBox (ActiveSheet.VLookup(LookFor, "A:A", 4, True))

and VBA throws error 438 object doesn't support this property or method

does anyone know why there’s an exception?

' Begin lookup :
Dim i As Integer, designator As String, LookFor As String
Flash.Activate
ActiveSheet.Range("C3").Select
For i = 3 To lastUsedCellInRow("C")
    designator = "C" + CStr(i)
    Dim cellVal As String
    cellVal = ActiveSheet.Range(designator).Value()
    If (Len(cellVal) <= 2 And IsNumeric(cellVal)) Then
        LookFor = ActiveSheet.Range(designator).Offset(0, 4).Value()
        RawData.Activate
        MsgBox (ActiveSheet.VLookup(LookFor, "A:A", 4, True))
    End If
Next i

Answer 1

You have several issues

1. You need to refer to the range as Range("A:A") not "A:A"
2. If you are using VLOOKUP rather than LOOKUP then as stated you need to be referring to a four column range , Range("A:D")
3. You need to handle your test value not being found in A

Sample code below for you to adapt

Dim strLookfor as String
Dim strOut
strLookfor = "test"
strOut = Application.VLookup(strLookfor, Range("A:D"), 4, True)
If IsError(strOut) Then
    MsgBox "value not found"
Else
'return column D value as string
    MsgBox CStr(strOut)
End If

Follow-up

Yes, you could use

`strOut = Application.VLookup(strLookfor & "*", Range("A:D"), 4, True)`

for this match

bu I think Find is cleaner, ie

Dim strLookfor As String
strLookfor = "F71"
Dim rng1 As Range
Set rng1 = Sheets("Sheet1").Columns("A").Find(strfolder & "*", , xlValues, xlPart)
If Not rng1 Is Nothing Then
    MsgBox "Match in " & rng1.Offset(0, 3)
Else
    MsgBox strfolder & "*" & vbNewLine & "not found"
End If