Home/ Questions/Q 8598741
In Process

The Archive Base Latest Questions

Editorial Team
  • 0
Asked: 2026-06-12T01:13:36+00:00

I have the following XML input <a href=h1 /> <a href=h2 /> <a href=h3

  • 0

I have the following XML input

<a href="h1" />
<a href="h2" />
<a href="h3" />

<b id="h1">E1</b>
<b id="h2">E1</b>
<b id="h3">E2</b>
<b id="h4">E3</b>
<b id="h5">E3</b>
<b id="h6">E4</b>
<b id="h7">E5</b>

Is there a way using XSLT2/Xpath2 to get only h1 and h3 referring to the distinct values E1 and E2 and ignore h2 since it refers to the same value E1?

Thanks.

Share

Leave an answer

You must login to add an answer.

Need An Account,

1 Answer

  1. Editorial Team

    Use, assuming a and b are children of the top element:

       for $href in /*/a/@href,
       $b in /*/b[@id = $href and not(. = preceding-sibling::b)]
     return
       string($href)

    XSLT – 2 based verification:

    <xsl:stylesheet version="2.0"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>

 <xsl:template match="/">
     <xsl:sequence select=
      "for $href in /*/a/@href,
           $b in /*/b[@id = $href and not(. = preceding-sibling::b)]
          return
             string($href)
      "/>
 </xsl:template>
</xsl:stylesheet>

    When this transformation is applied on the provided XML document:

    <html>
    <a href="h1" />
    <a href="h2" />
    <a href="h3" />
    <b id="h1">E1</b>
    <b id="h2">E1</b>
    <b id="h3">E2</b>
</html>

    the XPath expression is evaluated and the result of this evaluation is copied to the output:

    h1 h3

    Update:

    As fairly noted by Michael Kay, the above solution is O(N^2) and can be slow in case there are many b siblings.

    Here is an XSLT 2.0 solution that is at least linear (or faster):

    <xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kReferrer" match="b" use="@id"/>

 <xsl:template match="/*">
   <xsl:for-each-group select="key('kReferrer', a/@href)" group-by=".">
     <xsl:sequence select="string(@id)"/>
   </xsl:for-each-group>
 </xsl:template>
</xsl:stylesheet>

    Again, when this transformation is applied on the same XML document (above), the wanted, correct result is produced:

    h1 h3
    • 0