Question

I have to design a simply animation which should play next X frames with the click of forward button and previous X frames (in reverse order) with the click of backward button.
I have extensive experience in AS3 but i just don’t seem to get where to start in Flash Professional.

I have managed to get a button on the screen and some animation, I get the right trace when the button is clicked but I don’t get any further…

thanks for any help

cheers

Answer 1

You can try having a ticker variable that counts the frames to play. Just set this var on your button clicks. Then use an enterframe handler to go to the correct frame each frame. Example:

var maxFramesToPlay:int = 20;
var framesToPlay:int = 0;

addEventListener(Event.ENTER_FRAME, enterFrameHandler);
forwardButton.addEventListener(MouseEvent.CLICK, forwardClickHandler);
backButton.addEventListener(MouseEvent.CLICK, backClickHandler);

private function forwardClickHandler(e:MouseEvent):void 
{
    framesToPlay = maxFramesToPlay;
}

private function backClickHandler(e:MouseEvent):void 
{
    framesToPlay = -maxFramesToPlay;
}

private function enterFrameHandler(e:Event):void 
{
    if (framesToPlay > 0) 
    {
        MovieClip(this).nextFrame();
        framesToPlay--;
    }
    else if (framesToPlay < 0) 
    {
        MovieClip(this).prevFrame();
        framesToPlay++;
    }
    else 
    {
        // framesToPlay is zero, so don't do anything.
    }
}

You can put this functionality into a class that extends MovieClip, then in Flash just set it as the Document Class.