Question

I need to run a function that takes two arguments several times. I have two lists containing these arguments and I’d like to be able to use map or something similar to call the function with the corresponding args.

The function I want to call has this type:

runParseTest :: String -> String -> IO()

The lists are created like this:

-- Get list of files in libraries directory
files <- getDirectoryContents "tests/libraries"
-- Filter out ".." and "." and add path
let names = filter (\x -> head x /= '.') files
let libs = ["tests/libraries/" ++ f | f <- names]

So lets say that names contains ["test1.js", "test2.js", "test3.js"] and libs contains ["tests/libraries/test1.js", "tests/libraries/test2.js", "tests/libraries/test3.js"]

I want to call them like this:

runParseTest "test1.js" "tests/libraries/test1.js"
runParseTest "test2.js" "tests/libraries/test2.js"
runParseTest "test3.js" "tests/libraries/test3.js"

I know I could create a helper function that does this fairly easily, but out of interest, is it possible to do in one line using map?

This is what I have so far, but obviously the first argument is always “test”:

mapM_ (runParseTest "test") libs

I apologise if this is unclear. I can provide more info if necessary.

Answer 1

So lets say that names contains ["test1.js", "test2.js", "test3.js"]
and libs contains ["tests/libraries/test1.js", "tests/libraries/test2.js", "tests/libraries/test3.js"]

I want to call them like this:

runParseTest "test1.js" "tests/libraries/test1.js"
runParseTest "test2.js" "tests/libraries/test2.js"
runParseTest "test3.js" "tests/libraries/test3.js"

It’s possible to do that with zip:

map (\(a,b) -> runParseTest a b) $ zip names libs

Or maybe uncurry runParseTest:

 map (uncurry runParseTest) $ zip names libs

Or with zipWith:

 zipWith runParseTest names libs

And like Ozgur said, there are some analogues for monads:

> :t zipWithM
zipWithM :: Monad m => (a -> b -> m c) -> [a] -> [b] -> m [c]
> :t zipWithM_
zipWithM_ :: Monad m => (a -> b -> m c) -> [a] -> [b] -> m ()