Question

I need to write down a complicated MySQL query in perl.
I want to structure it in multiple lines.

Unfortunately,when using EOF notation perl inserts \n into my string.
Is there a way to write down a String in multiple lines, so that perl wont insert \n in it?
I eithr do not want to explicetly concat each line by a +.

Answer 1

No, but you can easily remove the lines after-the-fact. For example, this:

(my $query = <<'EOF') =~ s/\n */ /g;
    SELECT col1,
           MIN(col2)
      FROM t
     WHERE col3 > 17
     GROUP
        BY col1
EOF

print "$query\n";

will print this:

    SELECT col1, MIN(col2) FROM table t WHERE col3 > 17 GROUP BY col1

---

Edited to add:

A few things to note about the above:

• It’s O.K. to wrap a my-expression in parentheses; the variable is still scoped to the enclosing block.

• A my-expression evaluates to the variable that it declares, and you can continue to modify that variable. For example:

  (my $three) = 3;                        # same as:  my $three = 3;
  (my $four = 2) += 2;                    # same as:  my $four = 4;
  (my $five = 'twenty-five') =~ s/.*-//;  # same as:  my $five = 'five';
  

• The heredoc notation << starts the heredoc (the multiline string) on the following line. For example:

  my $abc = <<'EOF' . 'xyz';    # same as:  my $abc = "abc\nxyz";
  abc
  EOF
  

  In fact, this is actually very common; it’s slightly unusual for <<EOF to be the very last thing on the line, because if nothing else, there’s usually a semicolon after it to indicate the end of the statement.

  If you have multiple heredocs on the same line, then each one starts on the line after the previous one ends:

  my $abc = <<'EOF1' . <<'EOF2';    # same as:  my $abc = "abc\nxyz\n";
  abc
  EOF1
  xyz
  EOF2