Question

I want to wrap any tag that contains a href attribute into an <a> tag.

eg.

<img src="someimage.jpg" href="someurl.xml"/>

would become:

<a href="someurl.xml"><img src="someimage.jpg"/></a>

Answer 1

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <!--standard identity template that just copies content -->
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <!--For every element that has an href attribute-->
    <xsl:template match="*[@href]">
     <!--create an anchor element and an href attribute 
          with the value of the matched element's href attribute-->
        <a href="{@href}">
                   <!--then copy the matched element -->
            <xsl:copy>
                         <!--then apply templates (which will either match the 
                              identity template above or this template,
                              if any child elements have href attributes) -->
                <xsl:apply-templates select="@*|node()"/>
            </xsl:copy>
        </a>
    </xsl:template>

    <!--redact the href attribute-->
    <xsl:template match="*/@href"/>
</xsl:stylesheet>