Question

I’m trying to clean up some old data for a friend. The data is placed is multiple folders like the following.

1. C:\Tally\Data\0000
2. D:\Tally\Data\1092
3. C:\New folder\Tally7.2\Data\0001

Now, I’ve used a regular expression ^[0-9][0-9][0-9][0-9]$ with a search engine called Everything to find all the possible folders with four digit names like 0000 which I’ve exported to a text file containing a single directory path on every line, surrounded by double quotes on both sides.

I need to write a batch script to do the following.

1. Read the text file line by line.
2. Check if a folder with that name already exists in the destination directory.
3. If yes, then rename the folder and copy it.
4. If not, copy without renaming the folder.
5. Finally, I want to sequentially rename all the folders in the destination starting with 0000.

How can I accomplish this?

Answer 1

@echo off
setlocal EnableDelayedExpansion
set destination=C:\put the destination folder here
set newName=10000
rem Read the text file line by line
for /F "delims=" %%a in (thefile.txt) do (
   rem Check if a folder with that name already exists in the destination directory.
   set "folder=%%~Na"
   if exist "%destination%\!folder!" (
      rem If yes, then rename the folder and copy it.
      call :getNewName folder
   )
   rem If not, copy without renaming the folder.
   md "%destination%\!folder!"
   copy "%%~a" "%destination%\!folder!"
)
rem Finally, I want to sequentially rename all the folders in the destination starting with 0000. 
cd /D "%destination%"
set n=9999
for /D %%a in (*) do (
   set /A n+=1
   if "%%a" neq "!n:~-4!" (
      ren "%%a" "!n:~-4!"
   )
)
goto :EOF

:getNewName folder
   set /A newName-=1
   set folder=%newName%
   if exist "%destination%\%folder%" goto getNewName
exit /B