Question

In coffeescript we can do this way:

rows = [
    {a: 1}
    {b: 2}
]

for row in rows
    for k,v of row
        alert "#{k}: #{v}"

So why we can’t do that this way?:

for k,v of row for row in rows
    alert "#{k}: #{v}"

Answer 1

You cannot do it that way, but you can invert the inner loop and put the loop construct after the expression:

for row in rows
  alert "#{k}: #{v}" for k,v of row

And, as that inner loop is also an expression, you can also invert the outer loop the same way 😀

alert "#{k}: #{v}" for k,v of row for row in rows

The most similar to what you were trying to write is probably this:

for row in rows then for k,v of row 
  alert "#{k}: #{v}"

Which can be further inlined using another then (the then keyword is usually equivalent to a newline and adding one level of indentation):

for row in rows then for k,v of row then alert "#{k}: #{v}"

All of these alternatives generate the same JS code, so picking one or another will not result on degraded performance or anything like that 😀