Question

In my XSLT, I have used tokens to split substrings on a single delimiter (,) however how do I place a unique text to mark each substring? Thank you.

Example, XML document:

<list>1,4,7,9</list>

Desired output:

<w>1</w>
<x>4</x>
<y>7</y>
<z>9</z>

Answer 1

This XSLT 1.0 solution works for your example.

It recursively splits your input at a delimiter character and assigns individual parts to elements named according to a list you also supply as a parameter.

When either individual input parts or element names run out (whatever happens first), recursion stops.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template match="list">
    <xsl:call-template name="split">
      <xsl:with-param name="input" select="." />
      <xsl:with-param name="elems" select="'w,x,y,z'" />
      <xsl:with-param name="delim" select="','" />
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="split">
    <xsl:param name="input" select="''" />
    <xsl:param name="elems" select="''" />
    <xsl:param name="delim" select="','" />

    <xsl:if test="$elems != '' and $input != '' and $delim != ''">
      <xsl:variable name="curr-part" select="substring-before( concat($input, $delim), $delim)" />
      <xsl:variable name="curr-elem" select="substring-before( concat($elems, $delim), $delim)" />
      <xsl:element name="{$curr-elem}">
        <xsl:value-of select="$curr-part" />
      </xsl:element>
      <xsl:call-template name="split">
        <xsl:with-param name="input" select="substring-after($input, concat($curr-part, $delim))" />
        <xsl:with-param name="elems" select="substring-after($elems, concat($curr-elem, $delim))" />
        <xsl:with-param name="delim" select="$delim" />
      </xsl:call-template>
    </xsl:if>
  </xsl:template>

</xsl:stylesheet>

This template produces, with your input of <list>1,4,7,9</list>:

<w>1</w><x>4</x><y>7</y><z>9</z>

Note that the sample output is lacking a document element and therefore is not a valid XML document.