Question

This code populate a ListBox with the file names of a specific folder

Dim DIRECTORY As String
DIRECTORY = Dir(myPath & "\*.xlsx", vbNormal)
Do Until DIRECTORY = ""
ListBox1.AddItem DIRECTORY
DIRECTORY = Dir()
Loop

But I want a sorted list.
How can I sort the files firstly and then populate the ListBox.
btw sorting a listbox is (as I know) a long procedure.

Answer 1

A ListBox does not have a built in sort capability. You will need to roll your own.

The basic idea is to get the list data into an array, sort the array, and then put the data back in to the list. There are many good references avaliable for sorting VBA arrays.

Unless you have a very large number of files, a simple sort will probably suffice. Try This

Sub SortListBox(oLb As MSForms.ListBox)

Dim vItems As Variant
Dim i As Long, j As Long
Dim vTemp As Variant

'Put the items in a variant array
vItems = oLb.List

' Sort
For i = 0 To UBound(vItems, 1) - 1
    For j = i + 1 To UBound(vItems, 1)
        If vItems(i, 0) > vItems(j, 0) Then
            vTemp = vItems(i, 0)
            vItems(i, 0) = vItems(j, 0)
            vItems(j, 0) = vTemp
        End If
    Next
Next

'Clear the listbox
oLb.Clear

'Add the sorted array back to the listbox
For i = 0 To UBound(vItems, 1)
    oLb.AddItem vItems(i, 0)
Next

End Sub