Question

Trying to code a transform here in XSLT 2.0.

What my source document looks like (malformed but that is what I’m dealing with):

<p>
       <a>
           WANT TO GRAB TEXT NODE HERE
           <br/>
           <br/>
           <i> WORD </i> 
           DEFINITION TEXT NODE HERE
           <br/>
           <br/>
           <i> WORD </i> 
           DEFINITION TEXT NODE HERE
       </a>
</p>

My goal is to get this into our current DTD standard of a definition list so my output looks something along these lines:

<p> WANT TO GRAB TEXT NODE HERE </p>
<dl>
    <dlentry>
         <dt><i> WORD </i></dt>
         <dd> ANOTHER TEXT NODE HERE <dd>
         <dt><i> WORD </i></dt>
         <dd> ANOTHER TEXT NODE HERE <dd>
    <dlentry>
<dl>

Here is a code snippet from my current transform:

**<xsl:template match="a[descendant::i and descendant::br]/node()[1]">
   <p>
     <xsl:value-of select="." />
   </p> 
</xsl:template>**

<xsl:template match="p[string-length(.) gt 600]">
    <dl>
        <dlentry>
            <xsl:apply-templates />
        </dlentry>
    </dl>
</xsl:template>

<xsl:template match="i">
    <dt>
        <i>
            <xsl:value-of select="."/>
        </i>
    </dt>
</xsl:template>

<xsl:template match="text()[preceding-sibling::*[1][self::i]]">
    <dd>
        <xsl:value-of select="normalize-space()"/>
    </dd>
</xsl:template>

The output to my transform looks like this:

<dl>
    <dlentry>
         <p> WANT TO GRAB TEXT NODE HERE </p>
         <dt><i> WORD </i></dt>
         <dd> ANOTHER TEXT NODE HERE </dd>
         <dt><i> WORD </i></dt>
         <dd> ANOTHER TEXT NODE HERE </dd>
    </dlentry>
</dl>

I would like that <p> to be above <dl> and on the same level. Any ideas?

Thanks in advance.

Answer 1

This:

  <xsl:template match="p[string-length(.) &gt; 600]">
    <p>
      <xsl:value-of select="a/text()[1]"/>
    </p>
    <dl>
      <dlentry>
        <xsl:apply-templates select="a/node()[position()>1]"/>
      </dlentry>
    </dl>
  </xsl:template>

  <xsl:template match="i">
    <dt>
      <i>
        <xsl:value-of select="."/>
      </i>
    </dt>
  </xsl:template>

  <xsl:template match="text()[preceding-sibling::*[1][self::i]]">
    <dd>
      <xsl:value-of select="normalize-space()"/>
    </dd>
  </xsl:template>

should work – it handles the initial text node within the <a> tag separately, and then applies the templates on the other nodes (position()>1)