Home/ Questions/Q 9011397
In Process

The Archive Base Latest Questions

Editorial Team
  • 0
Asked: 2026-06-16T02:43:06+00:00

Would like to transform a price into a an expressed price range , so

  • 0

Would like to transform a price into a an expressed price range , so that I can say, for example, “Under $20” instead of $ 17.95. Using xml:choose is working for me, but when I try to put the result into a class attribute, I get an error:

Error during XSLT transformation: An unknown error has occurred ()

I’ve been reading up on xsl:variable but cannot seem to find the proper way to set the variable in this case.

The XML

    <?xml version="1.0" encoding="UTF-8"?>
    <productSearchResponse>
        <status>SUCCESS</status>
        <products found="20">
            <product>
                <itemNumber>50575</itemNumber>
                <itemName>Example 1</itemName>
                <price>$ 17.95</price>
            </product>

            ...

            <product>
                <itemNumber>81588</itemNumber>
                <itemName>Example 2</itemName>
                <price>$ 25.95</price>
            </product>
        </products>
    </productSearchResponse>

The stylesheet

<?xml version="1.0" encoding="UTF-8"?>          
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html"/>
<xsl:template match="/">
    <html>
        <head>
        </head>
        <body>
            <xsl:for-each select="/essentials/webservice">
                <xsl:for-each select="document(@filename)/productSearchResponse/products/product">                  
                    <xsl:variable name="producingCountry" select="producingCountry"/>
                    <xsl:variable name="price" select="price"/>
                    <xsl:variable name="priceNoSymbol" select="translate($price,'&#36;', '')"/> 

                    <!-- Assign pricing bands -->                       
                        <xsl:choose>                            
                            <xsl:when test="$priceNoSymbol &lt; '20'">  
                                <xsl:variable name="priceBand" select="'under20'" />
                            </xsl:when>                             
                            <xsl:when test="$priceNoSymbol &gt; '39.99'">   
                                <xsl:variable name="priceBand" select="'20to40'" />
                            </xsl:when>                             
                            <xsl:otherwise>
                                <xsl:variable name="priceBand" select="'over40'" /> 
                            </xsl:otherwise>                                
                        </xsl:choose>

                    <!-- Make the product div -->
                        <div class="product {$producingCountry} {$price} {$priceNoSymbol}     ">    
                        <!--           How do I insert priceBand into the class attribute? ^ -->    
                            <xsl:apply-templates select="itemName"/><br/>                           
                            <xsl:apply-templates select="producingCountry"/><br/>                       
                            <xsl:apply-templates select="price"/><br/><br/>                                                 
                        </div>

                </xsl:for-each>
            </xsl:for-each>
        </body>         
    </html>
</xsl:template>
</xsl:stylesheet>

The resulting html

    <html>
    <head>
        <body>

            <div class="product France $ 17.95 17.95 ">
                Example 1
                <br>
                France
                <br>
                $ 17.95
                <br>
                <br>
            </div>

            ...

            <div class="product Portugal $ 25.95 25.95 ">
                Example 2
                <br>
                Portugal
                <br>
                $ 25.95
                <br>
                <br>
            </div>

        </body>
    </html>

Desired html

    <html>
    <head>
        <body>

            <div class="product France $ 17.95 17.95 under20 ">
                Example 1
                <br>
                France
                <br>
                $ 17.95
                <br>
                <br>
            </div>

            ...

            <div class="product Portugal $ 25.95 25.95 20to40">
                Example 2
                <br>
                Portugal
                <br>
                $ 25.95
                <br>
                <br>
            </div>

        </body>
    </html>
Share

Leave an answer

You must login to add an answer.

Need An Account,

1 Answer

  1. Editorial Team

    I haven’t studied the entire question in detail, but you should replace

    <xsl:choose>                            
  <xsl:when test="$priceNoSymbol &lt; '20'">  
    <xsl:variable name="priceBand" select="'under20'" />
  </xsl:when>                             
  <xsl:when test="$priceNoSymbol &gt; '39.99'">   
    <xsl:variable name="priceBand" select="'20to40'" />
  </xsl:when>                             
  <xsl:otherwise>
    <xsl:variable name="priceBand" select="'over40'" /> 
  </xsl:otherwise>                                
</xsl:choose>

    with

    <xsl:variable name="priceband">
  <xsl:choose>                            
    <xsl:when test="$priceNoSymbol &lt; 20">under20</xsl:when>                             
    <xsl:when test="$priceNoSymbol &lt; 40">20to40</xsl:when>                             
    <xsl:otherwise>over40</xsl:otherwise>
  </xsl:choose>
</xsl:variable>

    and

    <xsl:variable name="priceNoSymbol" select="translate($price,'&#36;', '')"/>

    with

    <xsl:variable name="priceNoSymbol" select="number(translate($price,'&#36;', ''))"/>

    When you define a variable inside an xsl:when element like that, it goes out of scope almost immediately and isn’t available outside the xsl:choose.

    • 0